How to use SqlDataSource with ReportsV2 and pass the application connection string into the data source?

Hello Stephen,

I suppose that you meant the T192225 ticket. The ConfigureDataConnection event suggested there can be used to change connection parameters, but cannot change the connection name that is attempted to be loaded from the configuration file. As a workaround, you can add a connection string with the "localhost_sampledb_Connection" name to the configuration file. As I see, you already did this, so when I test your reports, they are shown without errors.
You can also change the connection name and connection parameters using the ReportDataSourceHelper.CustomSetupReportDataSource event provided by XAF. In this case, you will not need to declare a connection string with the "localhost_sampledb_Connection" name in the configuration file. Here is an example:

Visual Basic
Public Class ReportDataSourceController  
    Inherits WindowController  
    Public Sub New()  
        TargetWindowType = WindowType.Main  
    End Sub  
    Private _ReportsModuleV2 As ReportsModuleV2  
    Protected Overrides Sub OnActivated()  
        MyBase.OnActivated()  
        _ReportsModuleV2 = ReportsModuleV2.FindReportsModule(Application.Modules)  
        If _ReportsModuleV2 IsNot Nothing Then  
            AddHandler _ReportsModuleV2.ReportsDataSourceHelper.CustomSetupReportDataSource, AddressOf OnCustomSetupReportDataSource  
        End If  
    End Sub  
    Private Sub OnCustomSetupReportDataSource(ByVal sender As Object, ByVal e As CustomSetupReportDataSourceEventArgs)  
        If TypeOf e.Report.DataSource Is SqlDataSource Then  
            CType(e.Report.DataSource, SqlDataSource).ConnectionName = "ConnectionString"  
        End If  
        For Each subreport As XRSubreport In e.Report.AllControls(Of XRSubreport)()  
            If subreport.ReportSource IsNot Nothing Then  
                _ReportsModuleV2.ReportsDataSourceHelper.SetupReportDataSource(subreport.ReportSource, Nothing, False, Nothing, False)  
            End If  
        Next subreport  
    End Sub  
    Protected Overrides Sub OnDeactivated()  
        MyBase.OnDeactivated()  
        If _ReportsModuleV2 IsNot Nothing Then  
            RemoveHandler _ReportsModuleV2.ReportsDataSourceHelper.CustomSetupReportDataSource, AddressOf OnCustomSetupReportDataSource  
            _ReportsModuleV2 = Nothing  
        End If  
    End Sub  
End Class  

In addition, please note that we provide our own data sources integrated with XAF by default - CollectionDataSource and ViewDataSource. See how to use them in the Create a Report in Visual Studio topic.

I have created a separate ticket for your second question and will post my answer there: Cannot set report parameters' access modifier in the Report Designer at runtime.