How to calculate a running total of a column (accumulated by line)

Hi Leonard,
To accomplish this task, handle the 'COLIS DIS' field's OnCalculateCustomSummary event to calculate custom summary values for this field. The following code snippet represents the modified version of the 'Payment Amount' field's OnCalculateCustomSummary event handler from the OrderReportsDemo shipped with the ExpressPivotGrid Suite. This event handler calculates rolling totals accumulated by rows. To display custom summary values, set the 'Payment Amount' field's SummaryType property to stCustom.

Delphi
function VarToDouble(const AValue: Variant): Double;  
begin  
  Result := 0;  
  if not VarIsNull(AValue) then  
    Result := AValue;  
end;  

procedure TfrmOrderReport.pgfPaymentAmountCalculateCustomSummary(  
  Sender: TcxPivotGridField; ASummary: TcxPivotGridCrossCellSummary);  
var  
  AColumn: TcxPivotGridGroupItem;  
  APrevCrossCell: TcxPivotGridCrossCell;  
  APrevCrossCellSummary: TcxPivotGridCrossCellSummary;  
begin  
  inherited;  
  AColumn := ASummary.Owner.Column;  
  if (AColumn.Level = -1) then  
    // column grand totals  
    ASummary.Custom := ASummary.Sum  
  else begin  
    // all cells, except for column grand totals  
    // getting a custom summary calculated for the previous grouping value  
    if AColumn.PrevSibling <> nil then  
    begin  
      APrevCrossCell := AColumn.PrevSibling.GetCellByCrossItem(ASummary.Owner.Row);  
      APrevCrossCellSummary := APrevCrossCell.SummaryCells[Sender.SummaryIndex];  
      ASummary.Custom := VarToDouble(APrevCrossCellSummary.Custom) + VarToDouble(ASummary.Sum);  
    end else  
      ASummary.Custom := ASummary.Sum;  
  end;  
end;  

The following code snippet represents the 'Payment Amount' field's OnGetDisplayText event handler. This event handler displays a cell's rolling total and summary separated by a slash ('/').

Delphi
procedure TfrmOrderReport.pgfPaymentAmountGetDisplayText(  
  Sender: TcxPivotGridField; ACell: TcxPivotGridDataCellViewInfo;  
  var AText: String);  
begin  
  inherited;  
  AText := FloatToStr(VarToDouble(ACell.CellSummary.Custom)) + ' / ' +  
    FloatToStr(VarToDouble(ACell.CellSummary.Sum));  
end;  

Please let us know whether this solution makes sense.
Thanks,
Alex.

This works.
Thanks for All.
Leonard